Re: File changed during load

Lennart Borgman writes:

> I wonder what is going on?

  Can you run the following function in the buffer, to see the
`buffer-undo-list' value?

    (defun drkm:display-undo-list ()
      "Display the value of `buffer-undo-list´ in `*Undo List*´."
      (with-output-to-temp-buffer "*Undo List*"
        (dolist (entry buffer-undo-list)
          (cond
           ;; NIL
           ((null entry)
            (princ "Undo boundary\n"))
           ;; POSITION
           ((numberp entry)
            (princ "Point moved from ")
            (princ entry)
            (terpri))
           ;; From here, ENTRY must be a list.
           ;; (BEG . END)
           ((and (numberp (car entry)) (numberp (cdr entry)))
            (princ "Insertion from ")
            (princ (car entry))
            (princ " to ")
            (princ (cdr entry))
            (princ " of \"")
            (princ (buffer-substring (car entry) (cdr entry)))
            (princ "\"\n"))
           ;; (MARKER . DISTANCE)
           ((and (markerp (car entry)) (numberp (cdr entry)))
            (princ "Marker ")
            (princ (car entry))
            (princ " modified by ")
            (princ (cdr entry))
            (terpri))
           ;; (TEXT . POSITION)
           ((and (stringp (car entry)) (numberp (cdr entry)))
            (princ "Deletion ")
            (princ (if (< (cdr entry) 0) "before " "after "))
            (princ (abs (cdr entry)))
            (princ " of text \"")
            (princ (car entry))
            (princ "\"\n"))
           ;; (t HIGH . LOW)
           ((and (eq t (car entry))
                 (numberp (car (cdr entry)))
                 (numberp (cdr (cdr entry))))
            (princ "Buffer was marked unmodified here\n")
            (princ "  <TODO: When?  Use HIGN and LOW.>\n"))
           ;; (nil PROPERTY VALUE BEG . END)
           ((null (car entry))
            (princ "Property ")
            (princ (car (cdr entry)))
            (princ " modified\n")
            (princ "  <TODO: More precisely?>\n"))
           ;; (apply FUN-NAME . ARGS)
           ;; (apply DELTA BEG END FUN-NAME . ARGS)
           ((eq 'apply (car entry))
            (princ "Apply entry [")
            (prin1 entry)
            (princ "]\n"))
           (t
            (princ "UNKNOWN! [")
            (prin1 entry)
            (princ "]\n"))))
        (princ "Starting point\n")))

--drkm



------------------------ Yahoo! Groups Sponsor --------------------~--> 
<font face=arial size=-1><a 
href="http://us.ard.yahoo.com/SIG=12htrgjuu/M=362335.6886445.7839731.1510227/D=groups/S=1706030390:TM/Y=YAHOO/EXP=1123184273/A=2894361/R=0/SIG=13jmebhbo/*http://www.networkforgood.org/topics/education/digitaldivide/?source=YAHOO&cmpgn=GRP&RTP=http://groups.yahoo.com/";>In
 low income neighborhoods, 84% do not own computers. At Network for Good, help 
bridge the Digital Divide!</a>.</font>
--------------------------------------------------------------------~-> 

 
Yahoo! Groups Links

<*> To visit your group on the web, go to:
    http://groups.yahoo.com/group/emacs-nxml-mode/

<*> To unsubscribe from this group, send an email to:
    emacs-nxml-mode-unsubscribe@xxxxxxxxxxxxxxx

<*> Your use of Yahoo! Groups is subject to:
    http://docs.yahoo.com/info/terms/